Автор перевода: Майкл "Antares" Клишин	Предыдущая | Следующая | Оглавление

XML.appendChild()

Доступность

Flash Player 5.

Синтаксис

my_xml.appendChild(childNode:XMLNode) : Void

Параметры

childNode Объект XMLNode, определяющий узел, который будет перемещен из текущего положения в дереве в список дочерних узлов my_xml.

Возвращает

Ничего.

Описание

Метод; добавляет указанный узел в список дочерних узлов объекта XML. Этот метод оперирует непосредственно узлом, указанным в параметре childNode; при этом узел не копируется. Если добавляемый узел уже принадлежит какому-либо дереву, он будет удален из прежней локации после добавления. Если параметрchildNode ссылается на узел в дереве другого XML документа, этот узел будет добавлен в новую структуру после удаления из старой.

Пример

В следующем примере по порядку производятся следующие действия:

• Создаются два пустых XML документа, doc1 и doc2.
• При помощи метода createElement() создается новый узел, который затем при помощи метода appendChild() добавляется к XML документу doc1.
• Показывается перемещение узла при помощи метода appendChild()корневой узел перемещается из документа doc1 в документ doc2.
• Клонируется корневой узел из doc2 и добавляется в doc1.
• Создается новый узел и добавляется к корневому узлу XML документа doc1.

var doc1:XML = new XML();
var doc2:XML = new XML();

// Создаем новый корневой узел в объекте doc1
var rootnode:XMLNode = doc1.createElement("root");
doc1.appendChild(rootnode);
trace ("doc1: " + doc1); // Выведет: doc1: <root />
trace ("doc2: " + doc2); // Выведет: doc2:

// Перемещаем корневой узел, добавляя его в объект doc2
doc2.appendChild(rootnode);
trace ("doc1: " + doc1); // Выведет: doc1:
trace ("doc2: " + doc2); // Выведет: doc2: <root />

// Клонируем корневой узел и присоединяем его к объекту doc1
var clone:XMLNode = doc2.firstChild.cloneNode(true);
doc1.appendChild(clone);
trace ("doc1: " + doc1); // Выведет: doc1: <root />
trace ("doc2: " + doc2); // Выведет: doc2: <root />

// Создаем новый узел и присоединяем к корневому узлу (с именем clone) объекта doc1
var newNode:XMLNode = doc1.createElement("newbie");
clone.appendChild(newNode);
trace ("doc1: " + doc1); // Выведет: doc1: <root><newbie /></root>

Смотреть комментарии LiveDocs		Предыдущая | Следующая | Оглавление